home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 26 / Cream of the Crop 26.iso / os2 / octa209s.zip / octave-2.09 / libcruft / lapack / dormlq.f < prev    next >
Text File  |  1996-07-19  |  7KB  |  255 lines
  1.       SUBROUTINE DORMLQ( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC,
  2.      $                   WORK, LWORK, INFO )
  3. *
  4. *  -- LAPACK routine (version 2.0) --
  5. *     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
  6. *     Courant Institute, Argonne National Lab, and Rice University
  7. *     September 30, 1994
  8. *
  9. *     .. Scalar Arguments ..
  10.       CHARACTER          SIDE, TRANS
  11.       INTEGER            INFO, K, LDA, LDC, LWORK, M, N
  12. *     ..
  13. *     .. Array Arguments ..
  14.       DOUBLE PRECISION   A( LDA, * ), C( LDC, * ), TAU( * ),
  15.      $                   WORK( LWORK )
  16. *     ..
  17. *
  18. *  Purpose
  19. *  =======
  20. *
  21. *  DORMLQ overwrites the general real M-by-N matrix C with
  22. *
  23. *                  SIDE = 'L'     SIDE = 'R'
  24. *  TRANS = 'N':      Q * C          C * Q
  25. *  TRANS = 'T':      Q**T * C       C * Q**T
  26. *
  27. *  where Q is a real orthogonal matrix defined as the product of k
  28. *  elementary reflectors
  29. *
  30. *        Q = H(k) . . . H(2) H(1)
  31. *
  32. *  as returned by DGELQF. Q is of order M if SIDE = 'L' and of order N
  33. *  if SIDE = 'R'.
  34. *
  35. *  Arguments
  36. *  =========
  37. *
  38. *  SIDE    (input) CHARACTER*1
  39. *          = 'L': apply Q or Q**T from the Left;
  40. *          = 'R': apply Q or Q**T from the Right.
  41. *
  42. *  TRANS   (input) CHARACTER*1
  43. *          = 'N':  No transpose, apply Q;
  44. *          = 'T':  Transpose, apply Q**T.
  45. *
  46. *  M       (input) INTEGER
  47. *          The number of rows of the matrix C. M >= 0.
  48. *
  49. *  N       (input) INTEGER
  50. *          The number of columns of the matrix C. N >= 0.
  51. *
  52. *  K       (input) INTEGER
  53. *          The number of elementary reflectors whose product defines
  54. *          the matrix Q.
  55. *          If SIDE = 'L', M >= K >= 0;
  56. *          if SIDE = 'R', N >= K >= 0.
  57. *
  58. *  A       (input) DOUBLE PRECISION array, dimension
  59. *                               (LDA,M) if SIDE = 'L',
  60. *                               (LDA,N) if SIDE = 'R'
  61. *          The i-th row must contain the vector which defines the
  62. *          elementary reflector H(i), for i = 1,2,...,k, as returned by
  63. *          DGELQF in the first k rows of its array argument A.
  64. *          A is modified by the routine but restored on exit.
  65. *
  66. *  LDA     (input) INTEGER
  67. *          The leading dimension of the array A. LDA >= max(1,K).
  68. *
  69. *  TAU     (input) DOUBLE PRECISION array, dimension (K)
  70. *          TAU(i) must contain the scalar factor of the elementary
  71. *          reflector H(i), as returned by DGELQF.
  72. *
  73. *  C       (input/output) DOUBLE PRECISION array, dimension (LDC,N)
  74. *          On entry, the M-by-N matrix C.
  75. *          On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
  76. *
  77. *  LDC     (input) INTEGER
  78. *          The leading dimension of the array C. LDC >= max(1,M).
  79. *
  80. *  WORK    (workspace/output) DOUBLE PRECISION array, dimension (LWORK)
  81. *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
  82. *
  83. *  LWORK   (input) INTEGER
  84. *          The dimension of the array WORK.
  85. *          If SIDE = 'L', LWORK >= max(1,N);
  86. *          if SIDE = 'R', LWORK >= max(1,M).
  87. *          For optimum performance LWORK >= N*NB if SIDE = 'L', and
  88. *          LWORK >= M*NB if SIDE = 'R', where NB is the optimal
  89. *          blocksize.
  90. *
  91. *  INFO    (output) INTEGER
  92. *          = 0:  successful exit
  93. *          < 0:  if INFO = -i, the i-th argument had an illegal value
  94. *
  95. *  =====================================================================
  96. *
  97. *     .. Parameters ..
  98.       INTEGER            NBMAX, LDT
  99.       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
  100. *     ..
  101. *     .. Local Scalars ..
  102.       LOGICAL            LEFT, NOTRAN
  103.       CHARACTER          TRANST
  104.       INTEGER            I, I1, I2, I3, IB, IC, IINFO, IWS, JC, LDWORK,
  105.      $                   MI, NB, NBMIN, NI, NQ, NW
  106. *     ..
  107. *     .. Local Arrays ..
  108.       DOUBLE PRECISION   T( LDT, NBMAX )
  109. *     ..
  110. *     .. External Functions ..
  111.       LOGICAL            LSAME
  112.       INTEGER            ILAENV
  113.       EXTERNAL           LSAME, ILAENV
  114. *     ..
  115. *     .. External Subroutines ..
  116.       EXTERNAL           DLARFB, DLARFT, DORML2, XERBLA
  117. *     ..
  118. *     .. Intrinsic Functions ..
  119.       INTRINSIC          MAX, MIN
  120. *     ..
  121. *     .. Executable Statements ..
  122. *
  123. *     Test the input arguments
  124. *
  125.       INFO = 0
  126.       LEFT = LSAME( SIDE, 'L' )
  127.       NOTRAN = LSAME( TRANS, 'N' )
  128. *
  129. *     NQ is the order of Q and NW is the minimum dimension of WORK
  130. *
  131.       IF( LEFT ) THEN
  132.          NQ = M
  133.          NW = N
  134.       ELSE
  135.          NQ = N
  136.          NW = M
  137.       END IF
  138.       IF( .NOT.LEFT .AND. .NOT.LSAME( SIDE, 'R' ) ) THEN
  139.          INFO = -1
  140.       ELSE IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) ) THEN
  141.          INFO = -2
  142.       ELSE IF( M.LT.0 ) THEN
  143.          INFO = -3
  144.       ELSE IF( N.LT.0 ) THEN
  145.          INFO = -4
  146.       ELSE IF( K.LT.0 .OR. K.GT.NQ ) THEN
  147.          INFO = -5
  148.       ELSE IF( LDA.LT.MAX( 1, K ) ) THEN
  149.          INFO = -7
  150.       ELSE IF( LDC.LT.MAX( 1, M ) ) THEN
  151.          INFO = -10
  152.       ELSE IF( LWORK.LT.MAX( 1, NW ) ) THEN
  153.          INFO = -12
  154.       END IF
  155.       IF( INFO.NE.0 ) THEN
  156.          CALL XERBLA( 'DORMLQ', -INFO )
  157.          RETURN
  158.       END IF
  159. *
  160. *     Quick return if possible
  161. *
  162.       IF( M.EQ.0 .OR. N.EQ.0 .OR. K.EQ.0 ) THEN
  163.          WORK( 1 ) = 1
  164.          RETURN
  165.       END IF
  166. *
  167. *     Determine the block size.  NB may be at most NBMAX, where NBMAX
  168. *     is used to define the local array T.
  169. *
  170.       NB = MIN( NBMAX, ILAENV( 1, 'DORMLQ', SIDE // TRANS, M, N, K,
  171.      $     -1 ) )
  172.       NBMIN = 2
  173.       LDWORK = NW
  174.       IF( NB.GT.1 .AND. NB.LT.K ) THEN
  175.          IWS = NW*NB
  176.          IF( LWORK.LT.IWS ) THEN
  177.             NB = LWORK / LDWORK
  178.             NBMIN = MAX( 2, ILAENV( 2, 'DORMLQ', SIDE // TRANS, M, N, K,
  179.      $              -1 ) )
  180.          END IF
  181.       ELSE
  182.          IWS = NW
  183.       END IF
  184. *
  185.       IF( NB.LT.NBMIN .OR. NB.GE.K ) THEN
  186. *
  187. *        Use unblocked code
  188. *
  189.          CALL DORML2( SIDE, TRANS, M, N, K, A, LDA, TAU, C, LDC, WORK,
  190.      $                IINFO )
  191.       ELSE
  192. *
  193. *        Use blocked code
  194. *
  195.          IF( ( LEFT .AND. NOTRAN ) .OR.
  196.      $       ( .NOT.LEFT .AND. .NOT.NOTRAN ) ) THEN
  197.             I1 = 1
  198.             I2 = K
  199.             I3 = NB
  200.          ELSE
  201.             I1 = ( ( K-1 ) / NB )*NB + 1
  202.             I2 = 1
  203.             I3 = -NB
  204.          END IF
  205. *
  206.          IF( LEFT ) THEN
  207.             NI = N
  208.             JC = 1
  209.          ELSE
  210.             MI = M
  211.             IC = 1
  212.          END IF
  213. *
  214.          IF( NOTRAN ) THEN
  215.             TRANST = 'T'
  216.          ELSE
  217.             TRANST = 'N'
  218.          END IF
  219. *
  220.          DO 10 I = I1, I2, I3
  221.             IB = MIN( NB, K-I+1 )
  222. *
  223. *           Form the triangular factor of the block reflector
  224. *           H = H(i) H(i+1) . . . H(i+ib-1)
  225. *
  226.             CALL DLARFT( 'Forward', 'Rowwise', NQ-I+1, IB, A( I, I ),
  227.      $                   LDA, TAU( I ), T, LDT )
  228.             IF( LEFT ) THEN
  229. *
  230. *              H or H' is applied to C(i:m,1:n)
  231. *
  232.                MI = M - I + 1
  233.                IC = I
  234.             ELSE
  235. *
  236. *              H or H' is applied to C(1:m,i:n)
  237. *
  238.                NI = N - I + 1
  239.                JC = I
  240.             END IF
  241. *
  242. *           Apply H or H'
  243. *
  244.             CALL DLARFB( SIDE, TRANST, 'Forward', 'Rowwise', MI, NI, IB,
  245.      $                   A( I, I ), LDA, T, LDT, C( IC, JC ), LDC, WORK,
  246.      $                   LDWORK )
  247.    10    CONTINUE
  248.       END IF
  249.       WORK( 1 ) = IWS
  250.       RETURN
  251. *
  252. *     End of DORMLQ
  253. *
  254.       END
  255.